MPL Model Library

  
   {  Exmpl_9.5-1_MaxFlow.mpl  }

   {  Hillier and Lieberman, Introduction to Operations Research, 7th ed.  }

   {  Chapter 9.5,  Example 1, Maximum Flow,   Size: 7x14,  Page 420 }

TITLE
    MaximumFlow;

   
OPTIONS
   ExcelWorkbook="Exmpl_9.5-1_MaxFlow.xls"
   ExcelSheetName="SeervadaMaxFlow"

INDEX
    node := EXCELRANGE("Node");
   
    FromNode := node;
    ToNode   := node;

    SourceNode[node] := (O);
    DestNode[node]   := (T);


DATA
    Capacity[FromNode, ToNode] := EXCELSPARSE("NodeCapacity", 5);

VARIABLES
    Flow[FromNode, ToNode] -> x WHERE (Capacity > 0)
      EXPORT TO EXCELRANGE("Flow");
    Entrance[node=O];
    Destination[node=T];

MODEL

    MAX TotalFlow 
      EXPORT TO EXCELRANGE("MaxFlow")
      = Entrance[O];

SUBJECT TO

    FlowBalance[node]:

        Entrance + SUM(FromNode: Flow[FromNode,ToNode:=node])
      = 
        Destination + SUM(ToNode: Flow[FromNode:=node,ToNode]);

BOUNDS
    Flow <= Capacity;

END

Return to MPL Model Library